home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 11
/
FM Towns Free Software Collection 11.iso
/
t_os
/
edu
/
kana
/
src
/
mk_tiff.bas
< prev
Wrap
BASIC Source File
|
1995-07-12
|
4KB
|
121 lines
1000 '====================================================================
1010 '
1020 ' 『平仮名・片仮名の練習』画面作成
1030 ' by H.AOE 1995.07.06
1040 '====================================================================
1050 '
1060 *初期設定
1070 COLOR 7,0,7,0:CLS '画面クリア
1080 DEFINT A-Z '整数変数に設定
1090 CLEAR,,,,,300000 'フォント用DLL領域
1100 SCREEN 0 :SCREEN@ 0 'グラフィック1画面
1110 GOSUB *PALETTE 'パレット設定
1120 WINDOW(0,0)-(639,479):VIEW(0,0)-(639,479),%2 '16色モード
1130 '
1140 *ボタン作成
1150 '--------------------------------------------------------------------
1160 ' タイトル表示 ( 20, 20)-(399, 79)
1170 ' メインウインドウ ( 40,120)-(379,439)
1180 ' 五十音ボタン (420, 60)-(619,459)
1190 ' 読み書きスイッチ (420, 20)-(529, 49)
1200 ' 終了ボタン (540, 20)-(619, 49)
1210 '--------------------------------------------------------------------
1220 HIRA$="あいうえおかきくけこさしすせそたちつてとなにぬねのはひふへほまみむめもやゆよらりるれろわをん"
1230 KATA$="アイウエオカキクケコサシスセソタチツテトナニヌネノハヒフヘホマミムメモヤユヨラリルレロワヲン"
1240 '
1250 *タイトル表示
1260 DEF FONT"ゴシック体 32ドット"
1270 SX=20:EX=399:SY=20:EY=79:COL=13:GOSUB *BUTTON
1280 SYMBOL(30,27),"ひらがなのれんしゅう",2,3,%6,,,,4
1290 'SAVE@"TITLE_0.TIF",( 20, 20)-(399, 79)
1300 SX=20:EX=399:SY=20:EY=79:COL=13:GOSUB *BUTTON
1310 SYMBOL(30,27),"カタカナのれんしゅう",2,3,%6,,,,4
1320 'SAVE@"TITLE_1.TIF",( 20, 20)-(399, 79)
1330 '
1340 *メインウインドウ
1350 SX=20:EX=399:SY=100:EY=459:COL=7:GOSUB *BUTTON
1360 EX=40:SX=379:EY=120:SY=439:COL=15:GOSUB *BUTTON
1370 'SAVE@"MAIN_WIN.TIF",( 20,100)-(399,459)
1380 '
1390 *五十音ボタン
1400 GOJU$=HIRA$
1410 GOSUB *五十音
1420 'SAVE@"GOJU_0.TIF",(420, 60)-(619,459)
1430 GOJU$=KATA$
1440 GOSUB *五十音
1450 'SAVE@"GOJU_1.TIF",(420, 60)-(619,459)
1460 '
1470 *読み書きスイッチ
1480 DEF FONT"ゴシック体 24ドット"
1490 SX=420:EX=529:SY=20:EY=49:COL=2:GOSUB *BUTTON
1500 SYMBOL(SX+7,SY+3),"かきかた",1.5!,1.5!,%10
1510 'SAVE@"RW_0.TIF",(420, 20)-(529, 49)
1520 EX=420:SX=529:EY=20:SY=49:COL=2:GOSUB *BUTTON
1530 SYMBOL(EX+7,EY+3),"よみかた",1.5!,1.5!,%13
1540 'SAVE@"RW_1.TIF",(420, 20)-(529, 49)
1550 '
1560 *終了ボタン
1570 SX=540:EX=619:SY=20:EY=49:COL=2:GOSUB *BUTTON
1580 SYMBOL(SX+6,SY+3),"おわり",1.5!,1.5!,%10
1590 'SAVE@"EXIT_B.TIF",(540, 20)-(619, 49)
1600 '
1610 *終了
1620 'CLS
1630 'PALETTE
1640 END
1650 '
1660 *五十音
1670 FOR Y=0 TO 9
1680 FOR X=0 TO 4
1690 SX=X*40+420:EX=SX+37:SY=Y*40+60:EY=SY+37:COL=7
1700 GOSUB *BUTTON
1710 GOSUB *文字
1720 NEXT
1730 NEXT
1740 RETURN
1750 '
1760 *文字
1770 IF (Y=7 OR Y=9) AND (X=1 OR X=3) THEN RETURN
1780 MOJI=X+Y*5
1790 IF MOJI=37 THEN MOJI=36
1800 IF MOJI>38 THEN MOJI=MOJI-2
1810 IF MOJI=45 THEN MOJI=44 ELSE IF MOJI=47 THEN MOJI=45
1820 SYMBOL(SX+3,SY+3),KMID$(GOJU$,MOJI+1,1),2,2,%15
1830 RETURN
1840 '
1850 *BUTTON
1860 '--------------------------------------------------------------------
1870 ' (SX,SY)-(EX,EY)を対角とする四角形のボタンまたはウインドウを描く。
1880 ' (SX,SY)が左側のとき…ボタン (EX,EY)が左側のとき…ウインドウ
1890 ' COL:ボタン(ウインドウ)の色
1900 ' SX,SY,EX,EY,COLはすべて呼び出し側で指定する。
1910 '--------------------------------------------------------------------
1920 IF SX<>EX AND SY<>EY THEN
1930 LINE(SX,SY)-(EX,EY),PSET,%COL,BF
1940 PL=SGN(EX-SX)
1950 FOR A=0 TO 1
1960 CONNECT(SX+A*PL,EY-A*PL)-(SX+A*PL,SY+A*PL)-(EX-A*PL,SY+A*PL),%15
1970 CONNECT(EX-A*PL,SY+A*PL)-(EX-A*PL,EY-A*PL)-(SX+A*PL,EY-A*PL),%8
1980 NEXT
1990 ENDIF
2000 RETURN
2010 '
2020 *PALETTE
2030 PALETTE 0,[ 0, 0, 0]
2040 PALETTE 1,[ 0, 0,240]
2050 PALETTE 2,[128, 0,128]
2060 PALETTE 3,[192,240,176]
2070 PALETTE 4,[208,240,224]
2080 PALETTE 5,[176,240,112]
2090 PALETTE 6,[ 80,160, 48]
2100 PALETTE 7,[128,128,128]
2110 PALETTE 8,[ 64, 64, 64]
2120 PALETTE 9,[ 0,240, 0]
2130 PALETTE 10,[240, 0,192]
2140 PALETTE 11,[240, 0, 0]
2150 PALETTE 12,[240,112,128]
2160 PALETTE 13,[240,240,160]
2170 PALETTE 14,[240,240, 0]
2180 PALETTE 15,[255,255,255]
2190 RETURN